View of /trunk/webwork-modperl/lib/Apache/WeBWorK.pm

    1 ################################################################################
    2 # WeBWorK mod_perl (c) 2000-2002 WeBWorK Project
    3 # $Id$
    4 ################################################################################
    5 
    6 package Apache::WeBWorK;
    7 
    8 =head1 NAME
    9 
   10 Apache::WeBWorK - The WeBWorK dispatcher module.
   11 
   12 =cut
   13 
   14 use strict;
   15 use warnings;
   16 use Apache::Constants qw(:common REDIRECT);
   17 use Apache::Request;
   18 use WeBWorK::Authen;
   19 use WeBWorK::Authz;
   20 use WeBWorK::Constants qw(WEBWORK_HOME);
   21 use WeBWorK::ContentGenerator::Feedback;
   22 use WeBWorK::ContentGenerator::Login;
   23 use WeBWorK::ContentGenerator::Logout;
   24 use WeBWorK::ContentGenerator::Hardcopy;
   25 use WeBWorK::ContentGenerator::Options;
   26 use WeBWorK::ContentGenerator::Problem;
   27 use WeBWorK::ContentGenerator::ProblemSet;
   28 use WeBWorK::ContentGenerator::ProblemSets;
   29 use WeBWorK::ContentGenerator::Professor;
   30 use WeBWorK::ContentGenerator::Test;
   31 use WeBWorK::CourseEnvironment;
   32 
   33 # This module should be installed as a Handler for the location selected for
   34 # WeBWorK on your webserver. Here is an example of a stanza that can be added
   35 # to your httpd.conf file to achieve this:
   36 #
   37 # <IfModule mod_perl.c>
   38 #   PerlFreshRestart On
   39 #   <Location /webwork>
   40 #     SetHandler perl-script
   41 #     PerlHandler Apache::WeBWorK
   42 #     PerlSetVar webwork_root /path/to/webwork-modperl
   43 #     <Perl>
   44 #       use lib '/path/to/webwork-modperl/lib';
   45 #       use lib '/path/to/webwork-modperl/pglib';
   46 #     </Perl>
   47 #   </Location>
   48 # </IfModule>
   49 
   50 sub handler() {
   51   my $r = Apache::Request->new(shift); # have to deal with unpredictable GET or POST data, and sift through it for the key.  So use Apache::Request
   52 
   53   # This stuff is pretty much copied out of the O'Reilly mod_perl book.
   54   # It's for figuring out the basepath.  I may change this up if I
   55   # find a better way to do it.
   56   my $path_info = $r->path_info || "";
   57   my $current_uri = $r->uri;
   58   my $args = $r->args;
   59 
   60   $current_uri =~ m/^(.*)$path_info/;
   61   my $urlRoot = $1;
   62 
   63   # If it's a valid WeBWorK URI, it ends in a /.  This is assumed
   64   # alllll over the place.
   65   unless (substr($current_uri,-1) eq '/') {
   66     $r->header_out(Location => "$current_uri/" . ($args ? "?$args" : ""));
   67     return REDIRECT;
   68     # *** any post data gets lost here -- fix that.
   69   }
   70 
   71   # Create the @components array, which contains the path specified in the URL
   72   my($junk, @components) = split "/", $path_info;
   73   my $webwork_root = $r->dir_config('webwork_root'); # From a PerlSetVar in httpd.conf
   74   my $course = shift @components;
   75 
   76   # Try to get the course environment.
   77   my $course_env = eval {WeBWorK::CourseEnvironment->new($webwork_root, $urlRoot, $course);};
   78   if ($@) { # If there was an error getting the requested course
   79     # TODO: display an error page.  For now, 404 it.
   80     warn $@;
   81     return DECLINED;
   82   }
   83 
   84   # If no course was specified, redirect to the URL specified by the constant WEBWORK_HOME
   85   # (this is typically just "/".)
   86   unless (defined $course) {
   87     $r->header_out(Location => $course_env->{webworkURLs}->{home});
   88     return REDIRECT;
   89   }
   90 
   91   # Freak out if the requested course doesn't exist.  For now, this is just a
   92   # check to see if the course directory exists.
   93   if (!-e $course_env->{webworkDirs}->{courses} . "/$course") {
   94     warn "Course directory for $course not found at "
   95       . $course_env->{webworkDirs}->{courses} . "/$course" ."\n";
   96     return DECLINED;
   97   }
   98 
   99   ### Begin dispatching ###
  100 
  101   # WeBWorK::Authen::verify erases the passwd field and sets the key field
  102   # if login is successful.
  103   if (!WeBWorK::Authen->new($r, $course_env)->verify) {
  104     return WeBWorK::ContentGenerator::Login->new($r, $course_env)->go;
  105   } else {
  106     # After we are authenticated, there are some things that need to be
  107     # sorted out, Authorization-wize, before we start dispatching to individual
  108     # content generators.
  109     my $user = $r->param("user");
  110     my $effectiveUser = $r->param("effectiveUser") || $user;
  111     my $su_authorized = WeBWorK::Authz->new($r, $course_env)->hasPermissions($user, "become_student", $effectiveUser);
  112     $effectiveUser = $user unless $su_authorized;
  113     $r->param("effectiveUser", $effectiveUser);
  114 
  115     my $arg = shift @components;
  116     if (!defined $arg) { # We want the list of problem sets
  117       return WeBWorK::ContentGenerator::ProblemSets->new($r, $course_env)->go;
  118     } elsif ($arg eq "hardcopy") {
  119       my $hardcopyArgument = shift @components;
  120       $hardcopyArgument = "" unless defined $hardcopyArgument;
  121       return WeBWorK::ContentGenerator::Hardcopy->new($r, $course_env)->go($hardcopyArgument);
  122     } elsif ($arg eq "prof") {
  123       return WeBWorK::ContentGenerator::Professor->new($r, $course_env)->go;
  124     } elsif ($arg eq "options") {
  125       return WeBWorK::ContentGenerator::Options->new($r, $course_env)->go;
  126     } elsif ($arg eq "feedback") {
  127       return WeBWorK::ContentGenerator::Feedback->new($r, $course_env)->go;
  128     } elsif ($arg eq "logout") {
  129       return WeBWorK::ContentGenerator::Logout->new($r, $course_env)->go;
  130     } elsif ($arg eq "test") {
  131       return WeBWorK::ContentGenerator::Test->new($r, $course_env)->go;
  132     } else { # We've got the name of a problem set.
  133       my $problem_set = $arg;
  134       my $ps_arg = shift @components;
  135 
  136       if (!defined $ps_arg) {
  137         # list the problems in the problem set
  138         return WeBWorK::ContentGenerator::ProblemSet->new($r, $course_env)->go($problem_set);
  139       } else {
  140         # We've got the name of a problem
  141         my $problem = $ps_arg;
  142         return WeBWorK::ContentGenerator::Problem->new($r, $course_env)->go($problem_set, $problem);
  143       }
  144     }
  145 
  146   }
  147 
  148   # If the dispatcher doesn't know any modules that want to handle
  149   # the current path, it'll claim that the path does not exist by
  150   # declining the request.
  151   return DECLINED;
  152 }
  153 
  154 1;