FactoringAndExpanding

From WeBWorK_wiki
Revision as of 16:19, 14 May 2010 by Aubreyja (talk | contribs) (39 revisions: import all default namespace pages from old wiki)
Jump to navigation Jump to search

Factoring and Expanding Polynomials


This is the PG code to check answers that require students to factor or expand a polynomial expression.


  • Example 1: (Recommended) Using the PolynomialFactors context and the LimitedPowers context for factoring, and the LimitedPolynomial context for expanding.
  • Example 2: Using adaptive parameters and a MultiAnswer for factoring and the LimitedPolynomial context for expanding.


Example 1: (Recommended) Using the PolynomialFactors context and the LimitedPowers context for factoring and the LimitedPolynomial context for expanding.

Problem Techniques Index

PG problem file Explanation
DOCUMENT();
loadMacros(
"PGstandard.pl",
"MathObjects.pl",
"contextLimitedPolynomial.pl",
"contextPolynomialFactors.pl",
"contextLimitedPowers.pl",
);

TEXT(beginproblem()); 

Initialization: We need all of these macros.

#
#  Vertex form
#
Context("Numeric");
$n = list_random(4,6);
$a = random(2,4,1);
$b = ($a+$n);
$h = ($b-$a)/2;
$k = $h**2+$a*$b;
$vertexform = Compute("(x-$h)^2-$k");

#
#  Expanded form
#
Context("LimitedPolynomial-Strict");
$p[0] = $h**2 - $k;
$p[1] = 2*$h;
$expandedform = Formula("x^2 - $p[1] x + $p[0]")->reduce;

#
#  Factored form
#
Context("PolynomialFactors-Strict");
Context()->flags->set(singleFactors=>0);
LimitedPowers::OnlyIntegers(
minPower => 0, maxPower => 1,
message => "either 0 or 1",
);
$factoredform = Compute("(x+$a)(x-$b)");

Setup: To construct this quadratic, we choose a nice factored form (x+$a)(x-$b) and from it we construct its vertex form (a(x-h)^2+k) and expanded form (ax^2+bx+c).

For the expanded form we use the LimitedPolynomial-Strict context, construct the coefficients $p[0] and $p[1] as Perl reals, and then construct $expandedform using these pre-computed coefficients. This is because the LimitedPolynomial-Strict context balks at answers that are not already simplified completely.

For the factored form we need to change to the PolynomialFactors-Strict context and restrict the allowed powers to either 0 or 1 using the LimitedPowers::OnlyIntegers block of code. Note: restricting all exponents to 0 or 1 means that repeated factors will have to be entered in the form k(ax+b)(ax+b) instead of k(ax+b)^2. Also, restricting all exponents to 0 or 1 means that the polynomial must factor as a product of linear factors (no irreducible quadratic factors can appear). Of course, we could allow exponents to be 0, 1, or 2, but then students would be allowed to enter reducible quadratic factors. There are no restrictions on the coefficients, i.e., the quadratic could have any nonzero leading coefficient. We set singleFactors=>0 so that repeated, non-simplified factors do not generate errors.

Context()->texStrings;
BEGIN_TEXT
The quadratic expression \( $vertexform \)
is written in vertex form.
$BR
$BR
(a) Write the expression in expanded form 
\( ax^2 + bx + c \).
$BR
\{ ans_rule(30) \}
$BR
$BR
(b) Write the expression in factored form
\( k(ax+b)(cx+d) \).
$BR
\{ ans_rule(30)\}
END_TEXT
Context()->normalStrings;

Main Text: Everything here is as usual. To help students understand how to format their answers, we give examples ax^2+bx+c and k(ax+b)(cx+d) of what the answers should look like.

$showPartialCorrectAnswers = 1;

ANS( $expandedform->cmp() );
ANS( $factoredform->cmp() );

ENDDOCUMENT(); 

Answer Evaluation: Everything is as expected.




Example 2: Using adaptive parameters and a MultiAnswer for factoring and the LimitedPolynomial context for expanding.


Problem Techniques Index

PG problem file Explanation
DOCUMENT();

loadMacros(
"PGstandard.pl",
"MathObjects.pl",
"parserMultiAnswer.pl",
);

TEXT(beginproblem());

Initialization: We need to include the parserMultiAnswer.pl answer checker so we can take student answers from multiple answer blanks and check them as a whole.

Context("Numeric");

$fac1 = Compute("(2 x + 3)");
$fac2 = Compute("(8 x + 12)");

$multians = MultiAnswer($fac1,$fac2)->with(
   singleResult => 0,
   allowBlankAnswers => 0,

#  singleResult => 1,  
#  separator => " * ",
#  tex_separator => " \cdot ",

  checker => sub {
    my $correct = shift; my $student = shift; my $ansHash = shift;
    my ($F,$G) = @{$correct};
    my ($f,$g) = @{$student};

    $ansHash->setMessage(1,"Neither factor can be constant") 
    unless $f->isFormula;
    $ansHash->setMessage(2,"Neither factor can be constant") 
    unless $g->isFormula;

    #  use an adaptive parameter 'a'
    my $context = Context()->copy;
    $context->flags->set(no_parameters=>0);
    $context->variables->add('a'=>'Parameter');
    my $a = Formula($context,'a');
    $f = Formula($context,$f);
    $g = Formula($context,$g);
    $F = Formula($context,$F);
    $G = Formula($context,$G);

    if ( (($a*$F == $f) && ($F*$G == $f*$g)) ||
         (($a*$G == $f) && ($F*$G == $f*$g))
       ) 
    {
       return [1,1];
    } elsif (($a*$F == $f) || ($a*$G == $f)) {
       return [1,0];
    } elsif (($a*$F == $g) || ($a*$G == $g)) {
       return [0,1];
    } else {
       return [0,0];
    }

  }

);

Setup: This is a standard factoring problem for a non-monic polynomial (where the leading coefficient is not 1 or -1). Since it is possible to factor 16x^2 + 48 x + 36 as (2x+3)(8x+12) or (8x+12)(2x+3) or (4x+6)(4x+6), we need to allow any of these three factorizations to be marked correct. The MultiAnswer answer checker allows us to collect student answers from several answer blanks and perform answer evaluation on several answer blanks simultaneously, in particular allowing the factors to be entered in answer blanks in either order. The adaptive parameter allows us to effectively deal with passing a constant between the factors.

The MultiAnswer makes sure that neither factor is constant. Then, it creates a copy of the current context as a local context, and creates an adaptive parameter in this local context. The adaptive parameter will allow us to determine whether each factor in the student's answer is equal to a constant multiple of some factor of the correct answer.

For more details on adaptive parameters and MultiAnswer, please see AdaptiveParameters and MultiAnswerProblems.

Context()->texStrings;
BEGIN_TEXT
Factor the following expression.
$BR
$BR
\( 16 t^2 + 48 t + 36 = \big( \) 
\{$multians->ans_rule(10)\}
\( \big) \big( \) 
\{$multians->ans_rule(10)\}
\( \big) \)
END_TEXT
Context()->normalStrings;

Main Text: Each answer blank must be a method of the $multians object, which is why we use $multians->ans_rule(10). The big parentheses will help students understand what the format of the answer should be.

$showPartialCorrectAnswers = 1;

install_problem_grader(~~&std_problem_grader);

ANS( $multians->cmp() );

ENDDOCUMENT(); 

Answer Evaluation: Everything is as expected. We give students feedback on whether their answers are correct by using $showPartialCorrectAnswers = 1;, but withhold credit until both factors are correct by using the standard problem grader.

Problem Techniques Index