** Using WeBWorK **

One complication that you have is dealing with the "2 n pi" part. My feeling is that this is going to cause more trouble in your problem than it is worth. For example, if you haven't used "n" in the problem, how are you going to tell them to type their answer using an "n"? What if the student entered "2 k pi + pi/2" instead? Would you want that to be marked wrong? How about "pi/2 - 2 n pi"? It seems to me that the number of possible ways to specify this equivalence class is too large to handle effectively with the current tools in WeBWorK. I don't like the idea of asking a student to be precise about his answer, but not be able to be precise about the checking.

My recommendation would be to make the "2 n pi" be assumed, for example by asking something like "the angle is 2 n pi + [_____]" rather than have the students need to enter 2 n pi in their answers.

This checking is easily accomplished:

    BEGIN_TEXT
    The angle is \(2 n \pi +\) \{ans_rule(20)\} 
    END_TEXT
    ANS(Real(pi/2)->cmp(checker => sub {
      my ($correct,$student) = @_;
      return 0 unless $student->class eq 'Real';
      my $a = ($correct-$student)/(2*pi)->value;
      return abs($a - int($a)) < .00001;
    }));

It might be easier to use the custom_cmp wrapper that does some extra typechecking like that for you:

    loadMacros("answerCustom.pl");
    BEGIN_TEXT
    The angle is \(2 n \pi +\) \{ans_rule(20)\} 
    END_TEXT
    ANS(custom_cmp(Real(pi/2),sub {
      my ($correct,$student) = @_;
      my $a = ($correct-$student)/(2*pi)->value;
      return abs($a - int($a)) < .00001;
    }));

If you really must have the "2 n pi" as part of the answer, then you can try the following:

    ANS(custom_cmp($f,sub {
      my ($correct,$student) = @_;
      my $context = $correct->{context};
      $context->variables->add(a => 'Parameter');
      $context->flags->set(no_parameters => 0);
      $__correct = $correct + "2 a pi"; $__student = $student;
      my $equal = PG_restricted_eval('$__correct == $__student');
      $context->flags->set(no_parameters => 1);
      $context->variables->remove('a');
      return 0 unless $equal;
      my $d = $__correct->{test_values}[0] - $__student->{test_values}[0];
      my $a = $d/(2*pi)->value;
      return abs($a - int($a)) < .00001;
    }));

To do this, we temporarily add a parameter 'a' to the context (and enable the use of parameters, which has been turned off so that students can't enter them), and then create a new formula that is the old correct answer plus "2 a pi". (We could have just used "a", but this makes it clearer what you are going to be doing). We make global copies of this new function ($__correct) and the student function ($__student) so that we can do the comparison inside of PG_restricted_eval(), that way, if there are any error messages due to problems with the student answer, they will not appear on screen anywhere (and since PG_restricted_eval() operates in the main:: namespace, not the current one, the formulas can't be local to the checker subroutine).

We perform the check to see if the student's formulas does equal the professor's up to a constant, and then put the Context() back the way it was (we hope), and return incorrect if they were not equal. If they where equal up to a constant, we need to check if the constant is a multiple of 2pi, so we find the difference between two of the test points, and check if we get a (near) interger after dividing by 2pi.

You might want to report a special hint if the student has typed an answer without "2 n pi", since they are not going to think if this themselves. Here is one possible modification to allow that:

   ANS(custom_cmp($f,sub {
     my ($correct,$student,$ans) = @_;
     Value::Error("Remember that there is always more than one answer")
        if $student->class eq 'Real' && !$ans->{isPreview};
     return 0 unless $student->class eq 'Formula';
     my $context = $correct->{context};
     $context->variables->add(a => 'Parameter');
     $context->flags->set(no_parameters => 0);
     $__correct = $correct + "2 a pi"; $__student = $student;
     my $equal = PG_restricted_eval('$__correct == $__student');
     $context->flags->set(no_parameters => 1);
     $context->variables->remove('a');
     return 0 unless $equal;
     my $d = $__correct->{test_values}[0] - $__student->{test_values}[0];
     my $a = $d/(2*pi)->value;
     return abs($a - int($a)) < .00001;
   },sameClass => 0));

These last two solutions suffer from the problem I mentioned at the beginning: they require the student to use "n" as the variable, and they must use "2 n pi" and not "-2 n pi" or some other formula that gets the same set of points but in a different relation to n.

Davide

<| Post or View Comments |>