** Using WeBWorK **

The problem has to do with the way lists do their checking, and how (or actually when) the Fraction object does the reduction check. The reduction check is done within the Fraction object's post-processing of the answer checker, and but the list checker doesn't actually call that (because it is not part of the equality check that it is doing to compare student entries to correct ones). This has come up before, and probably means that the pos-processing code should be refactored, but such changes are delicate with such a complicated package like MathObjects.

Anyway, the solution (to both problems, as it turns out) is to use a custom checker for the list check. Note that for a list object, checker refers to the checker used to compare individual entries in the list to correct ones, not to a checker for the entire list (which is list_checker. I give a modified version of the key parts of the code below:

    DOCUMENT();
    
    loadMacros(
      "PGstandard.pl",
      "MathObjects.pl",
      "contextFraction.pl"
    );
    
    TEXT(beginproblem());
    $showPartialCorrectAnswers = 1;
    
    Context("Fraction-NoDecimals");
    Context()->strings->add(
      "no solution"=>{},
      "none"=>{alias=>"no solution"}
    );
    Context()->flags->set(reduceFractions=>0);
    
    $var = list_random('x','y','z','w','p','q','r','s','t','u','v');
    Context()->variables->are($var => 'Real');
    
    $a = random(2,20)*random(-1,1,2);
    $b = -sgn($a)*random(1,20);
    $k = non_zero_random(-15,15);
    
    $eqn = "$k - \left| $a $var + $b\right| = $k";
    $answer = List("-$b/$a,1/2");
    
    BEGIN_TEXT
    Solve the following equation for \($var\):
    $PAR
    \[ $eqn \]
    $PAR
    \( $var = \) \{ ans_rule(20) \}
    END_TEXT

    ANS($answer->cmp(
      entry_type=>"a fraction",
      checker => sub {
        my ($correct,$student,$ans,$nth,$value) = @_;
        return 0 unless Value::classMatch($student,'Fraction');
        return $correct == $student if $student->isReduced;
        $correct->context->setError("Your $nth $value is not reduced","",undef,undef,$Value::CMP_WARNING)
          unless $ans->{isPreview};
        return 0;
      }
    )); 
    
    ENDDOCUMENT();

The main change is in the custom checker. We set the entry_type to "a fraction" so that the error messages will be a bit better (otherwise it would be "fraction of integers" which is awkward in most of the messages).

The checker itself gets that correct and student answers, plus the answer hash and strings that can be used for error messages to indicate which list entry ($nth) we are, and what type of object ($value). We return 0 (no correct) if the student answer isn't a fraction (among other things, this will take care of the case where they enter "no solution" without causing an error message). Then, if the student's answer is reduced, return whether it equals the correct answer or not. Othewise (not reduced), print a warning message (unless we are previewing the asnwers), and return 0 (no correct).

That should do what you want, I hope.

Davide