** Using WeBWorK **

Currently it does not. (You can get entry hints for vectors and points, but not matrices). But you can certainly arrange for it with a custom checker or a post-filter.

Here is an example that uses the post-filter approach (for reasons I'll explain below).

sub MatrixPartialCredit {
  my $N = shift;   # number of entries that must be right for partial credit
  return sub {
    my $ans = shift; $ans->{_filter_name} = "Matrix Partial Credit";
    my $correct = $ans->{correct_value};
    my $student = $ans->{student_value};
    if ($ans->{score} < 1 && defined($correct) &&
          defined($student) && $student->class eq "Matrix") {
      my @c = map {@$_} ($correct->value);   # flatten matrix
      my @s = map {@$_} ($student->value);   # flatten matrix
      my $score = 0; my $n = @c;
      foreach my $i (0..$#c) {$score ++ if $c[$i] == $s[$i]}
      $ans->score($score/$n) if $score >= $N;
    }
    return $ans;
  }
}

Context("Matrix");

$M = Matrix([1,2],[3,4]);

BEGIN_TEXT
\{$M->ans_array\}
END_TEXT

ANS($M->cmp->withPostFilter(MatrixPartialCredit(3)));

If both are valid, then we get an array of all the entries of the matrix ($M->value returns an array of references to arrays, where the references are to arrays that are the rows of the matrix; the entries of the rows are Real MathObjects). We then compare the correct and student arrays entry by entry (and since these are Real objects, they will use the fuzzy checks controlled by the tolerance and tolType context flags), and add up the number of entries that are equal. If enough of them are equal, then we adjust the score to be the proper percentage. Finally, we return the AnswerHash.

You could put the MatrixPartialCredit() filter in a separate file and load that into whatever problems need it.

You could have done this in a custom checker without having to do the checks of whether the values are defined or the correct type, but there are two reasons to use the filter approach instead, even though there is a little more checking to do.

First, you can more easily add messages like "Your entry (2,3) is incorrect" if you wanted to help the student out more. (But because there are so many entries, it might be better to make an array-like layout that has X for incorrect entries or something like that.)

Second, it would allow you to check matrices that are not completely filled in, though you would have to work a bit to get the data about the matrix in that case, because the Matrix MathObject is not actually created when there are blank entries. So that is more sophisticated. But if you use the post-filter approach with a macro file for MatrixPartialCredit(), then you could update that macro file at some time in the future to handle partially filled matrices, and all your existing problems would take advantage of that automatically.

Hope that does what you need.

TEXT(MODES(TeX=>"",HTML=>"<style>table.ArrayLayout td {background-color:transparent}</style>")); 

sub MatrixMarkIncorrect {
  my $right = "&#x2714;";
  my $wrong = "&#x2718;";
  return sub {
    my $ans = shift; $ans->{_filter_name} = "Matrix Mark Incorrect";
    my $correct = $ans->{correct_value};
    my $student = $ans->{student_value};
    if ($ans->{score} < 1 && defined($correct) && defined($student)) {
      my @c = $correct->value;
      my @s = $student->value;
      @s = @{$ans->{student_formula}} if ref($ans->{student_formula}) eq 'ARRAY';
      foreach my $i (0..$#c) {
        foreach my $j (0..scalar(@{$c[$i]})-1) {
          my $ca = $c[$i][$j]; my $sa = $s[$i][$j];
          $s[$i][$j] = ($ca == $sa ? "[$right]" : "[$wrong]") if ref($sa);
        }
      }
      $ans->{ans_message} = "Incorrect entries are marked with '$wrong':<p>".
        $correct->format_matrix([@s],@{$correct->{format_options}},tth_delims=>1)."<br><br>";
      $ans->{ans_message} =~ s/~~n//g;
    }
    return $ans;
  }
}

Context("Matrix");
$M = Matrix([1,2],[3,4]);

BEGIN_TEXT
\{$M->ans_array\}
END_TEXT
ANS($M->cmp->withPostFilter(MatrixMarkIncorrect));

The code above goes through the correct answer and the student answer and (when the student answer is filled in) checks it against the correct answer and changes the array to a checkmark or an "x". At the end, it uses the format_matrix() method to turn the array into the HTML for displaying the matrix (just like in the "Entered" column). One caveat is that you have to remove the newlines or they will be turned into <br> elements automatically by the code that creates the table. I also added some CSS to get the coloration to be correct for the table.

You should be able to combine this with the previous filter to get partial credit as well. E.g.,

ANS($M->cmp->withPostFilter(MatrixPartialCredit(3))->withPostFilter(MatrixMarkIncorrect));