** Using WeBWorK **

    #
    #  Define a prime subclass of the unary operator class
    #
    package my::UOP::prime;
    our @ISA = ('Parser::UOP');

    #
    #  Do a typecheck on the operand
    #
    sub _check {
      my $self = shift;
      return if $self->checkInfinite || $self->checkString || 
                $self->checkList || $self->checkNumber;
      $self->{type} = {%{$self->{op}->typeRef}};
    }

    #
    #  A hack to prevent double-primes from inserting parentheses
    #   in string and TeX output (change the precedence to hide it)
    #
    sub string {
      my ($self,$precedence,$showparens,$position,$outerRight) = @_;
      my $uop = $self->{def}; $precedence -= .01 if $uop->{precedence} == $precedence;
      return $self->SUPER::string($precedence,$showparens,$position,$outerRight);
    }
    sub TeX {
      my ($self,$precedence,$showparens,$position,$outerRight) = @_;
      my $uop = $self->{def}; $precedence -= .01 if $uop->{precedence} == $precedence;
      return $self->SUPER::TeX($precedence,$showparens,$position,$outerRight);
    }

    #
    #  Add prime to the given or current context
    #
    sub Enable {
      my $self = shift; my $context = shift || main::Context();
      $context->operators->add("'"=>{
        precedence => 8.5, associativity => "right", type => "unary", string => "'",
        class => "my::UOP::prime", isCommand => 1
      });
    }

    sub Disable {
      my $self = shift; my $context = shift || main::Context();
      $context->operators->remove("'");
    }

The Enable routine is the one you call to add the operator to the current context. You can put the code into a macro file (either in the same directory with the problems that use it, or in the course templates/macros directory, or somewhere else in the macros path). If you call it "parserPrime.pl", then code that uses it could look like:

    loadMacros(
      "PGstandard.pl",
      "MathObjects.pl",
      "parserPrime.pl"
    );

    Context("Numeric")->variables->add(y=>'Real');        #  set the context
    my::UOP::prime->Enable;    #  add primes to it

    #  create $a, $b, c here

    $f = Formula("$a y'' + $b y' + $c y")->reduce;
    $ans = Formula("..whatever...");

    Context()->texStrings;
    BEGIN_TEXT
    Find the general solution to \($f = 0\):
    \{ans_rule(30)\}
    END_TEXT
    Context()->normalStrings;

    my::UOP::prime->Disable;  # don't allow students to enter primes
    ANS(Formula($ans)->cmp);

It's a little complicated, but can be done. Note that this is for display purposes only. Primes can NOT be used in the student or correct answers, as we have not implemented the eval method, which is needed for that. To do it right, we would also need to implement call and perl to handle the derivatives, though I'm not sure everything would work out for that.

Hope that helps.

Davide