** Using WeBWorK **

This can be resolved by making the following change: set the reduceConstantFunctions context flag to 0, so that the square root of a constant will be retained in the formula as an actual square root (this is done automatically for student answers, but not professor formulas). This is done using:

    Context()->flags->set(reduceConstantFunctions=>0);

For the 2*sqrt(3), not only is the square root a constant, the whole answer is a constant, so Compute("2*sqrt(3)") returns a MathObject Real (approximately 3.4641), not a formula, and the student's answer of sqrt(12) returns the same real, so they are counted as equal.

This can be resolved by adding the following two lines to the checker:

    $student = $ans->{student_formula};
    $correct = $correct->{original_formula} if defined $correct->{original_formula};

    return 0 if $ans->{isPreview} || $correct != $student;

Note that a student MUST enter sqrt(6) rather than a numeric value, so if she enters x*2.44949, it will be marked wrong (with the error "check to see if your answer is simplified"). Not the best error, but it would take some more work to do better.

Finally, note that the results table will show the student answer in the "entered" column as the numeric result rather than the parsed formula. You may want to change that to reflect the fact that you care about the form, not just the number. Adding formatStudentAnswer=>"reduced" to the cmp() call will do that, even when the correct answer is a constant.

So here is the updated version that should work for all your answers.

    DOCUMENT(); 

    loadMacros(
      "PGstandard.pl", # Standard macros for PG language
      "MathObjects.pl",
      "contextLimitedPowers.pl"
    );

    # Print problem number and point value (weight) for the problem
    TEXT(beginproblem());

    # Show which answers are correct and which ones are incorrect
    $showPartialCorrectAnswers = 1;

    # code essentially from Davide Cervone 4/25/10
    ###########################
    #
    # Subclass the numeric functions
    #
    package my::Function::numeric;
    our @ISA = ('Parser::Function::numeric');

    #
    # Override sqrt() to return a special value (usually 1) when evaluated
    # effectively eliminating it from the product.
    #
    sub sqrt {
      my $self = shift;
      my $value = $self->context->flag("setSqrt");
      return $value+1 if $value && $_[0] == 1; # force sqrt(1) to be incorrect
      return $value if $value;
      return $self->SUPER::sqrt(@_);
    }

    #
    # end of subclass
    #
    package main;

    ###########################

    Context("Numeric")->variables->are(
      x => ["Real", limits => [0,2]],    # only needed if x is used in the square roots
    );
    #
    # make sqrt() use our subclass
    #
    Context()->functions->set(sqrt=>{class=>'my::Function::numeric'});
    Context()->flags->set(reduceConstantFunctions=>0);
    #
    # Don't allow fractional powers (avoids 1/2 power)
    # [Could subclass exponentiation to handle that as well]
    #
    LimitedPowers::OnlyPositiveIntegers();

    $f = Compute("x*sqrt(6)");

    BEGIN_TEXT
    $BR
    9. \{ans_rule(20)\}
    END_TEXT

    #
    # Use a custom checker to check that the answers are equivalent
    # and that they are still equivalent when sqrt() is replaced by 1
    # (so the stuff outside the sqrt() is equal in both)
    #
    ANS($f->cmp(checker => sub {
      my ($correct,$student,$ans) = @_;
      return 0 if $ans->{isPreview} || $correct != $student;
      #
      #  Get parsed formula for student and correct answers
      #
      $student = $ans->{student_formula};
      $correct = $correct->{original_formula} if defined $correct->{original_formula};
      #
      # check if equal when sqrt's are replaced by 1
      #
      Context()->flags->set(setSqrt => 1);
      delete $correct->{test_values}, $student->{test_values};
      my $OK = ($correct == $student);
      Context()->flags->set(setSqrt => 0);
      #
      Value::Error("Check to see if your answer is simplified.") unless $OK;
      return $OK;
    },formatStudentAnswer=>"reduced"));

The formatStudentAnswer flag could be set in the Context instead of including it in cmp() if you perfer.

Hope that does it.

Davide